java-bowler/build.gradle at development · NeuronRobotics/java-bowler · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
buildscript {

	dependencies {
		classpath 'org.eclipse.jdt:org.eclipse.jdt.core:3.35.0'
		classpath 'org.eclipse.platform:org.eclipse.text:3.14.0'
	}
}
import groovy.xml.XmlSlurper
import org.eclipse.jdt.core.ToolFactory
import org.eclipse.jdt.core.formatter.CodeFormatter
import org.eclipse.jface.text.Document
plugins {
	id 'java'
	id 'eclipse'
	id 'java-library'
	id 'signing'
	id 'maven-publish'
	id 'com.diffplug.spotless'
}

spotless {
	java {
		lineEndings = com.diffplug.spotless.LineEnding.UNIX
		custom('eclipseFormatterDirect') { String source ->
			def configFile = new File(projectDir, 'config/eclipse-formatter.xml')
			def options = new HashMap<String, String>()
			def xml = new XmlSlurper().parse(configFile)
			xml.profile.setting.each { setting ->
				options[setting.@id.text()] = setting.@value.text()
			}
			def formatter = ToolFactory.createCodeFormatter(options, ToolFactory.M_FORMAT_EXISTING)
			def edit = formatter.format(
					CodeFormatter.K_COMPILATION_UNIT,
					source, 0, source.length(), 0, System.lineSeparator()
					)
			if (edit == null) {
				throw new GradleException("Eclipse formatter returned null — source may have a syntax error")
			}
			def doc = new Document(source)
			edit.apply(doc)
			doc.get()
		}
		removeUnusedImports()
		trimTrailingWhitespace()
		endWithNewline()
	}
}

java {
	withJavadocJar()
	withSourcesJar()
}

tasks.withType(JavaCompile).configureEach {
	options.encoding = 'UTF-8'
}

File buildDir = file(".")

Properties props = new Properties()
props.load(new FileInputStream(buildDir.getAbsolutePath() + "/src/main/resources/com/neuronrobotics/sdk/config/build.properties"))

sourceSets {
	test {
		java {
			srcDirs = ["test/java/src"]
		}
	}
}

jar {
	manifest {
		attributes(
		"Manifest-Version": "1.0",
		"Created-By": "Neuron Robotics Cooperative",
		"Specification-Title": props."app.name",
		"Specification-Version": props."app.version",
		"Specification-Vendor": "Neuron Robotics Cooperative",
		"Implementation-Title": props."app.name",
		"Implementation-Version": props."app.version",
		"Implementation-Vendor": "Neuron Robotics Cooperative"
		)
	}
	if (project == rootProject) {
		archiveFileName.set("nrsdk-${props.'app.version'}-jar-with-dependencies.jar")
	}
}

repositories {
	mavenCentral()
}

dependencies {
	api fileTree(dir: 'libs', includes: ['*.jar'])
	testImplementation 'junit:junit:4.12'
	implementation 'com.google.code.gson:gson:2.5'

	api 'gov.nist.math:jama:1.0.2'
	implementation 'com.miglayout:miglayout-swing:4.1'
	implementation 'org.igniterealtime.smack:smack:3.2.1'
	implementation 'org.igniterealtime.smack:smackx:3.2.1'
	implementation 'org.apache.commons:commons-lang3:3.2.1'
	api 'org.usb4java:usb4java:1.2.0'
	api 'org.usb4java:usb4java-javax:1.2.0'
	api 'com.neuronrobotics:nrjavaserial:5.1.1'
	api group: 'org.apache.commons', name: 'commons-math3', version: '3.6.1'
	api group: 'net.sf.bluecove', name: 'bluecove-gpl', version: '2.1.0'
	api group: 'io.ultreia', name: 'bluecove', version: '2.1.1'
}

group = "com.neuronrobotics"
version = props."app.version"

base {
	archivesName = "java-bowler"
}

publishing {
	publications {
		mavenJava(MavenPublication) {
			from components.java
			artifactId = 'java-bowler'

			pom {
				name = 'Java Bowler'
				packaging = 'jar'
				description = 'A command line utility for accessing the bowler framework.'
				url = 'http://neuronrobotics.com'

				scm {
					connection = 'scm:git:https://github.com/NeuronRobotics/java-bowler.git'
					developerConnection = 'scm:git:git@github.com:NeuronRobotics/java-bowler.git'
					url = 'https://github.com/NeuronRobotics/java-bowler'
				}

				licenses {
					license {
						name = 'The Apache License, Version 2.0'
						url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
					}
				}

				developers {
					developer {
						id = 'madhephaestus'
						name = 'Kevin Harrington'
						email = 'kharrington@neuronrobotics.com'
					}
				}
			}
		}
	}
}

signing {
	sign publishing.publications.mavenJava
}